; PROGRAMMING RESTRICTIONS:
;   SPEED HAS ABSOLUTE PRIORITY OVER SIZE
;   THIS MODULE MUST BE AS FAST AS POSSIBLE

; P: 268+128=396 clks max
; S: 2 levels (for DO loops)
; USES R0, R1, R4, N4, R5, X0, X1, Y0, Y1, A, B

        SETUP   RCVSUM
        OPT     NOCC,CEX,CL,CM,NOFC,MC,MD,MEX,PS,NORC,NOU,W,NOXR
        PAGE    132,66,2,3,0
        IF      !@SCP('RCVSUM','GLOBAL')
        SECTION RCVSUM
SETUP__ EQU     1
        ENDIF
        ORG     P;
        INCLUDE '..\DSP\DEFN.ASM'
; DSP ; COMMON DEFINITIONS for assembler :
;       END
;       LIST
        XDEF    RCVSUM

; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; notes
        COMMENT ~
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; history

; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; data

X FAST ram
  VOLUSEL
  SUMUSEL

Y FAST ram
  VOLSEL
  SUMSEL

Y ram
  RCV_FRAME

I/O
  IO_PCMCVT
  IO_SEL
  IO_USEL

; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
~ end of COMMENT
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

CVT     MACRO
;This macro converts 16-bit linear audio values to 8-bit A-law PCM
;P: 38+7*2=38+14=52 clks max
;S: 2 levels (for DO loop)
;uses A, B, R0, X1, Y1
        TFR     A,B                             ;SAVE LINEAR FOR SIGN
        ABS     A       #>TBL+7,R0              ;MAKE LINEAR POSITIVE ;LAST TABLE ENTRY
        DO      #7,_LOOP                        ;DO "NORMALIZE"
        NORM    R0,A                            ; TO FIND SEGMENT
_LOOP
        JNN     <_SEG0                          ;SEG 0?
        LSL     A                               ; NO, FORCE "1" INTO SIGN BIT
_SEG0                                           ;(A1 SIGN BIT IS PCM BIT S0)
        MOVE    A1,A                            ;SET A2 TO SIGN OF A1
        ASR     A                               ; AND SHIFT A1 S0 PUT IN PCM S1
        ASR     A                               ; AND PCM S2 AS COPIES OF S0
                                                ;(SEG IS NOW 0 OR 7)
        MOVE    P:R0,X1                         ;GET SEGMENT MASK
        AND     X1,A                            ; AND MAKE CORRECT SEG BITS
        LSL     B                               ;BRING LINEAR SIGN BIT
        ROR     A                               ; OVER TO PCM
        EOR     Y1,A                            ;DO BIT INVERSIONS
        ENDM

RCVSUM
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; MULTIPLY AND ACCUMULATE SELECT & UNSELECT

; P: 28+30*8=28+240=268 clks
; S: 2 levels (for DO loop)
; USES R0, R1, R4, R5, X0, Y0, Y1, A, B

        OPT     CC
        MOVE            #>RCV_FRAME+1, R1           ;point to receive frame slot#1 (in Y)
        MOVE            #>IO_PCMCVT,R4              ;point to PCM-to-linear I/O location
        MOVE            #<VOLUSEL+1,R0              ;point to unsel vol slot#1 (in X)
        MOVE            #<VOLSEL+1,R5               ;point to   sel vol slot#1 (in Y)
        MOVEP           Y:(R1)+,Y:<<IO_PCMCVT       ;output 1st PCM on bits 23-16
                                                    ; Linear is input on bits 23-08
        CLR     B       X:(R0)+,X0      Y:(R4),Y0   ;clear unsel ;load 1st unsel ;linear in
        CLR     A                       Y:(R5)+,Y1  ;clear   sel ;load 1st   sel
        DO      #PCM_SIZE-2,_LOOP2                  ;process only receive slots #1-30
        MOVEP           Y:(R1)+,Y:<<IO_PCMCVT       ;output PCM on bits 23-16
        MAC     Y0,Y1,A                 Y:(R5)+,Y1  ;update   sel ;load next sel vol
        MAC     Y0,X0,B X:(R0)+,X0      Y:(R4),Y0   ;update unsel ;unsel vol ;linear in
_LOOP2
; UPPER 13 BITS OF A1 AND B1 NOW CONTAIN VALID LINEAR VALUES
; (ANY OVERFLOW OF 13 BITS WENT INTO A2 AND B2)

; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; LINEAR-TO-PCM CONVERSION

; PROGRAMMING RESTRICTIONS:
;   CAN ONLY USE R0
;
;   the _CVT routine seemed too complicated to duplicate in-line

; P: 100+7*2+7*2=100+14+14=128 clks
; S: 2 levels (for DO loop in CVT)
; USES R0, X0, X1, Y1, A, B

; references: Motorola App Note ANE008, Logarithmic/Linear Conversion Routines
;   for DSP56000/1, routine ALINLG2.ASM

; enter with A1=sel sum and B1=unsel sum

        OPT     CC
        MOVE            #<$D5,Y1                ;for polarity and even bit inversion
        MOVE            A1,X0                   ;get linear sel sum
        MOVE                       Y:<SUMSEL,X1 ;get master sel vol
        MPY     X0,X1,A B1,X0                   ;master sel in A ;save unsel sum in B
        CVT                                     ;[52 clks] convert sel (destroys A&B)
        MOVEP           A1,Y:<<IO_SEL           ;output sel pcm

        MOVE            X:<SUMUSEL,X1           ;get  master unsel vol
        MPY     X0,X1,A                         ;make master unsel (linear)
        CVT                                     ;[52 clks] convert unsel (destroys A&B)
        MOVEP           A1,Y:<<IO_USEL          ;output unsel pcm
        RTS                                     ;exit ***

TBL
        DC      $1E0000,$3E0000,$5E0000,$7E0000,$9E0000,$BE0000,$DE0000,$FE0000

; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ENDEND